How to write an ARRAYFORMULA + REGEXMATCH formula to search through a column of values ​​from an array?

Question

Google Sheets

Help me figure it out, it only works line by line, or if you choose each one separately.
Here is the formula that works

=ARRAYFORMULA(if(A:A="";;
  REGEXMATCH(A:A;"Седьмой")
))

And what I need is that I would not select each separately as described above, but something like this, but with such a formula, the search is only for a complete match of cells ...

=ARRAYFORMULA(if(A:A="";;
  REGEXMATCH(A:A;D:D)
))

Answer 1

Maybe,

=ARRAYFORMULA(IF(A2:A="";;
  REGEXMATCH(A2:A;"(" & TEXTJOIN("|";1;D2:D) & ")")
))

But I doubt that I understood the task correctly

. Alternatively, you need to display the values ​​A:A from the search results.

=ARRAYFORMULA(
  IF(
    (A2:A<>"") * REGEXMATCH(A2:A;"(" & TEXTJOIN("|";1;D2:D) & ")");
    A2:A;

))

If we need to know the criterion that worked during the search, then REGEXMATCH will not work, we need to use a search by string

=ARRAYFORMULA(TRANSPOSE(TRIM(QUERY(
  IF(IFERROR(FIND(B2:B5;TRANSPOSE(A2:A7));"");B2:B5;);
  ;
  9^9
))))