No report from computer on WSUS console?

Question

System administration

On the WSUS console (see picture) 2 computers are not synchronized. (They do not send a report) I will throw off the
logs from the problem client, please see what it is connected with and where to dig.

Answer 1

Perhaps you need to reset the kerberos ticket ( https://technet.microsoft.com/en-us/library/cc7386...

Answer 2

A familiar problem... I solve it lazily:
The script is run from the administrator's workplace, with elevated rights, the PStools package must be installed, the names of computers with update errors can be viewed in the WSUS console.
It is also very desirable to reject unnecessary updates in WSUS and clean up the WsusContent folder - it helps to avoid such situations.
Bat file:
------------------------------------

@echo off > nul

echo.
echo Скрипт для исправления ошибок обновления Windows 7
echo.
echo На компьютере должен быть установлен комплект pstools
echo.
echo Запуск скрипта - обязательно от имени администратора.
echo.

:: Enter %computername% - from WSUS errors

set /p X="Введите имя компьютера: "

:: Stop services

psservice \\%X% stop bits
psservice \\%X% stop wuauserv

:: Waiting...

ping -n 6 127.0.0.1 > nul

:: Check and rename folder SoftwareDistribution

if exist "\\%X%\c$\Windows\SoftwareDistribution_bak" rd /s /q "\\%X%\c$\Windows\SoftwareDistribution_bak"

ren "\\%X%\c$\Windows\SoftwareDistribution\" SoftwareDistribution_bak

:: Wait again...

ping -n 6 127.0.0.1 > nul

:: Start services

psservice \\%X% start bits
psservice \\%X% start wuauserv

:: Wait untill services are started...

ping -n 6 127.0.0.1 > nul

:: Query services

echo.
echo.

psservice \\%X% query bits
psservice \\%X% query wuauserv

psexec -s \\%X% wuauclt.exe /updatenow

:: Done!

echo.
echo Папка SoftwareDistribution пересоздана, клиент обновления перезапущен.
echo.

pause

exit

-------------------------------------
I.e. the Sofrware Distribution folder is recreated on the problem computer and the update client is restarted. After a day or two, everything returns to normal, you can speed up and force the update of problem computers, but this is not necessary.

Answer 3

There can be many reasons.
But often this problem is caused by the old version of the CryptoPro program - this is a crypto provider widely used in Russia in client-bank systems, exchanging documents with tax authorities, etc. Usually it is set and never updated later.
Check if CryptoPro is installed on these computers - the problem may be in this, it is solved by installing the patch.
If not, then you need to figure it out.