How to remove Adobe Flash Player built into Windows 8.1?

Question

Adobe Flash

After updating the OS, it installed for Internet Explorer. Since I do not use Flash Player in this OS, I would like to find an opportunity to remove it without third-party software.

Answer 1

This question is also of interest, but already in relation to 10.
How to delete it in a normal way, that is, so that it is not set again and no longer updated without dumb crutches has not yet been found. But there was a way to disable it, at least in IE, as in other places - it's also not clear.
gpedit.msc
Computer Configuration Internet explorer
Administrative Templates Security Tools Disable Adobe Flash in Internet Explorer and prevent applications from using Internet Explorer technology to instantiate Flash objects Addition: Wrote a batch file to uninstall Flash Player, albeit crutch but reliable.
The bottom line is this: first we remove all installed versions that are in the list of installed programs, and then, taking into account whether the 32 or 64 bit system is used, we clean the folder with Flash Player executable files under the root.

@echo off

echo FlashPlayer secure cleanup begin...

echo uninstall all previos version begin...

wmic product where "name like 'Adobe Flash Player%%'" call uninstall /nointeractive

echo uninstall all previos version end.

echo extendent secure cleanup begin...

if %PROCESSOR_ARCHITECTURE% == AMD64 (

  set TARGET_PLATFORM=AMD64

  rem take ownership
  takeown /f "%SYSTEMROOT%\SysWOW64\Macromed\Flash\*.*"
  
  rem extend access
  cacls "%SYSTEMROOT%\SysWOW64\Macromed\Flash\*.*" /E /T /G %UserDomain%\%UserName%:F

  rem delete
  del /q /f "%SYSTEMROOT%\SysWOW64\Macromed\Flash\*.*"
  rd /s /q "%SYSTEMROOT%\SysWOW64\Macromed\Flash"
  rd /s /q "%SYSTEMROOT%\SysWOW64\Macromed"
  del /q /f "%SYSTEMROOT%\SysWOW64\FlashPlayerApp.exe"
  del /q /f "%SYSTEMROOT%\SysWOW64\FlashPlayerCPLApp.cpl"

) else (
  set TARGET_PLATFORM=Win32
)

rem take ownership
takeown /f "%SYSTEMROOT%\System32\Macromed\Flash\*.*"

rem extend access
cacls "%SYSTEMROOT%\System32\Macromed\Flash\*.*" /E /T /G %UserDomain%\%UserName%:F

rem delete
del /q /f "%SYSTEMROOT%\System32\Macromed\Flash\*.*"
rd /s /q "%SYSTEMROOT%\System32\Macromed\Flash"
rd /s /q "%SYSTEMROOT%\System32\Macromed"
del /q /f "%SYSTEMROOT%\System32\FlashPlayerApp.exe"
del /q /f "%SYSTEMROOT%\System32\FlashPlayerCPLApp.cpl"

echo extendent secure cleanup end.

echo FlashPlayer secure cleanup end.

PS At 8 and older, this crutch will have to be launched after each system update in which there will be a Flash Player, because the system will install it again.
PPS Flash finally everything, cheers!

Answer 2

You feel sorry for the extra 16MB on the screw?